Gerçekten ama bu kodu düzeltmem gerek XSL bilmiyorum, bunu daha basit bir hale indirgenmiş.
Bu hatayı alıyorum

XPath işlevi . geçersiz XSLT/

bu hat üzerinde

<xsl:variable name="text" select="replace($text,'a','b')"/>

Bu XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

Herkes sorunun ne olduğunu söyleyebilir mi?

replace XSLT 1.0 için mevcut değil.

Codesling işlevi için bir yedek olarak kullanabilirsiniz. template for string-replace bir:

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

olarak çağrılan:

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

Eğer gerçekten sadece başka bir karakteri değiştirmek için gerekirse diğer taraftan, benzer bir imza olan translate diyebilirsin. Böyle bir şey iyi çalışması gerekir:

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

Ayrıca, Not, Bu örnekte, değiştirdim değişken adı "newtext", XSLT değişkenler değişmez, o yüzden yapamazsın eşdeğer $foo = $foo gibi ... ... orijinal kodu.